使用ESP32-CAM构建Wi-Fi间谍摄像头的完整指南

本文详细介绍了如何使用ESP32-CAM模块构建一个具备人脸检测和识别功能的Wi-Fi间谍摄像头，包括硬件连接、Arduino IDE配置、代码修改和电源解决方案等完整步骤。

如何用ESP32-CAM设置Wi-Fi间谍摄像头

所需部件

进行此项目需要以下基本材料：

  • ESP32-CAM摄像头模块与FTDI USB转TTL串行转换器（12.89美元）
  • D1 Mini电池扩展板与充电模块（8.99美元）
  • 3.7V 500mAh锂聚合物电池（9.20美元）
  • 免焊面包板（8.99美元）
  • 跳线（5.99美元）
  • Mini-USB数据线（6.81美元）
  • Arduino IDE软件（免费）

注意：电池可以根据需要选择不同尺寸。

在Arduino IDE中设置摄像头

在Arduino IDE中，导航到菜单栏中的"Arduino"或"文件"，选择"首选项"，然后点击"附加开发板管理器URL"旁边的窗口图标。在新行中添加以下URL，然后选择"确定"两次。

1

https://dl.espressif.com/dl/package_esp32_index.json

接下来，在菜单栏中转到"工具"，然后"开发板"，再选择"开发板管理器"。在搜索字段中输入"esp32"，然后安装最新版本的"esp32 by Espressif Systems"。

打开默认摄像头示例

再次在菜单栏中转到"工具"，选择"开发板"，然后在"ESP32 Arduino"部分下选择"AI Thinker ESP32-CAM"。选择该开发板后，转到文件 -> 示例 -> ESP32 -> Camera -> CameraWebServer。这将打开示例代码。

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112

#include "esp_camera.h"
#include <WiFi.h>

//
// 警告!!! UXGA分辨率和高JPEG质量需要PSRAM IC
// 确保选择ESP32 Wrover模块或其他带有PSRAM的开发板
// 如果图像超过缓冲区大小，将传输部分图像
//

// 选择摄像头型号
#define CAMERA_MODEL_WROVER_KIT // 有PSRAM
//#define CAMERA_MODEL_ESP_EYE // 有PSRAM
//#define CAMERA_MODEL_M5STACK_PSRAM // 有PSRAM
//#define CAMERA_MODEL_M5STACK_V2_PSRAM // M5Camera版本B有PSRAM
//#define CAMERA_MODEL_M5STACK_WIDE // 有PSRAM
//#define CAMERA_MODEL_M5STACK_ESP32CAM // 无PSRAM
//#define CAMERA_MODEL_AI_THINKER // 有PSRAM
//#define CAMERA_MODEL_TTGO_T_JOURNAL // 无PSRAM

#include "camera_pins.h"

const char* ssid = "*********";
const char* password = "*********";

void startCameraServer();

void setup() {
  Serial.begin(115200);
  Serial.setDebugOutput(true);
  Serial.println();

  camera_config_t config;
  config.ledc_channel = LEDC_CHANNEL_0;
  config.ledc_timer = LEDC_TIMER_0;
  config.pin_d0 = Y2_GPIO_NUM;
  config.pin_d1 = Y3_GPIO_NUM;
  config.pin_d2 = Y4_GPIO_NUM;
  config.pin_d3 = Y5_GPIO_NUM;
  config.pin_d4 = Y6_GPIO_NUM;
  config.pin_d5 = Y7_GPIO_NUM;
  config.pin_d6 = Y8_GPIO_NUM;
  config.pin_d7 = Y9_GPIO_NUM;
  config.pin_xclk = XCLK_GPIO_NUM;
  config.pin_pclk = PCLK_GPIO_NUM;
  config.pin_vsync = VSYNC_GPIO_NUM;
  config.pin_href = HREF_GPIO_NUM;
  config.pin_sscb_sda = SIOD_GPIO_NUM;
  config.pin_sscb_scl = SIOC_GPIO_NUM;
  config.pin_pwdn = PWDN_GPIO_NUM;
  config.pin_reset = RESET_GPIO_NUM;
  config.xclk_freq_hz = 20000000;
  config.pixel_format = PIXFORMAT_JPEG;

  // 如果存在PSRAM IC，使用UXGA分辨率和更高的JPEG质量初始化
  // 用于更大的预分配帧缓冲区
  if(psramFound()){
    config.frame_size = FRAMESIZE_UXGA;
    config.jpeg_quality = 10;
    config.fb_count = 2;
  } else {
    config.frame_size = FRAMESIZE_SVGA;
    config.jpeg_quality = 12;
    config.fb_count = 1;
  }

#if defined(CAMERA_MODEL_ESP_EYE)
  pinMode(13, INPUT_PULLUP);
  pinMode(14, INPUT_PULLUP);
#endif

  // 摄像头初始化
  esp_err_t err = esp_camera_init(&config);
  if (err != ESP_OK) {
    Serial.printf("摄像头初始化失败，错误代码 0x%x", err);
    return;
  }

  sensor_t * s = esp_camera_sensor_get();
  // 初始传感器垂直翻转且颜色有点饱和
  if (s->id.PID == OV3660_PID) {
    s->set_vflip(s, 1); // 翻转回来
    s->set_brightness(s, 1); // 稍微提高亮度
    s->set_saturation(s, -2); // 降低饱和度
  }
  // 降低帧尺寸以获得更高的初始帧率
  s->set_framesize(s, FRAMESIZE_QVGA);

#if defined(CAMERA_MODEL_M5STACK_WIDE) || defined(CAMERA_MODEL_M5STACK_ESP32CAM)
  s->set_vflip(s, 1);
  s->set_hmirror(s, 1);
#endif

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi已连接");

  startCameraServer();

  Serial.print("摄像头就绪！使用 'http://");
  Serial.print(WiFi.localIP());
  Serial.println("' 连接");
}

void loop() {
  // 将主代码放在这里，重复运行：
  delay(10000);
}

调整示例代码

在默认的CameraWebServer示例中，我们需要确保选择了AI Thinker开发板而不是其他开发板。目前，以下开发板没有被注释掉：

1

#define CAMERA_MODEL_WROVER_KIT // 有PSRAM

您需要在该行开头添加//，然后从此行开头移除//：

1

//#define CAMERA_MODEL_AI_THINKER // 有PSRAM

现在代码中的该部分应该如下所示：

1
2
3
4
5
6
7
8
9

// 选择摄像头型号
//#define CAMERA_MODEL_WROVER_KIT // 有PSRAM
//#define CAMERA_MODEL_ESP_EYE // 有PSRAM
//#define CAMERA_MODEL_M5STACK_PSRAM // 有PSRAM
//#define CAMERA_MODEL_M5STACK_V2_PSRAM // M5Camera版本B有PSRAM
//#define CAMERA_MODEL_M5STACK_WIDE // 有PSRAM
//#define CAMERA_MODEL_M5STACK_ESP32CAM // 无PSRAM
#define CAMERA_MODEL_AI_THINKER // 有PSRAM
//#define CAMERA_MODEL_TTGO_T_JOURNAL // 无PSRAM

然后，我们需要输入要连接间谍摄像头的Wi-Fi网络的SSID名称和密码。找到这两行，然后用您的Wi-Fi网络名称和密码替换星号。

1
2

const char* ssid = "*********";
const char* password = "*********";

这样就完成了示例代码的自定义。点击编译按钮进行编译，然后就可以将程序刷写到ESP32-CAM上了。

连接ESP32-CAM

使用FTDI编程器和ESP32-CAM模块，使用带或不带面包板的跳线将FTDI编程器和ESP32-CAM模块连接在一起。

  • 将FTDI上的GND连接到ESP32-CAM上的GND（靠近U0T）
  • 将FTDI上的5V连接到ESP32-CAM上的5V
  • 将FTDI上的TX连接到ESP32-CAM上的U03
  • 将FTDI上的RX连接到ESP32-CAM上的U0T
  • 将ESP32-CAM上的I00连接到旁边的GND

最后一个连接是将CAM模块短路，以便可以将其置于编程模式。

将代码上传到ESP32-CAM

所有跳线就位后，您可以使用Mini-USB数据线将其连接到计算机，然后上传代码。

在Arduino IDE中找到ESP32-CAM连接的端口。首先，转到"工具"，选择"开发板"，然后在"ESP32 Arduino"部分下选择"AI Thinker ESP32-CAM"（如果您尚未执行此操作）。

接下来，转到"工具"，选择"端口"，然后如果尚未自动选择，请更改为正确的端口。请格外注意您已为ESP32-CAM选择了正确的端口，因为您不会希望覆盖任何其他设备。

要将Wi-Fi代码刷写到ESP32-CAM，请点击上传按钮（左上角的右箭头）。您将看到一系列操作。一旦屏幕上出现红色文本，您就知道它实际上正在刷写。完成后，您可以使用Control-Shift-M打开串行监视器，确保没有严重错误或电压下降，并查找重新启动。

将代码刷写到ESP32-CAM后，在串行监视器中查找开发板的IP地址。稍后您将需要这个地址。

为ESP32-CAM寻找电源

现在您的ESP32-CAM已编程，您可以断开FTDI编程器的连接；只有在以后需要更新间谍摄像头上的代码时才需要再次使用它。如果您想通过这种方式为摄像头供电，也可以在仍连接到ESP32-CAM时将恒定电源连接到FTDI编程器，但由于我们希望它是一个间谍摄像头，电池会更好。

将ESP32-CAM从面包板上断开，然后将其连接到D1 Mini电池扩展板，这将使我们能够使用小型锂聚合物电池为间谍摄像头供电。连接它们时，请确保两个板上的5V引脚正确对齐。然后，使用其两针JST-PH连接器将锂离子聚合物电池连接到电池扩展板。我使用的是3.7伏500毫安时的电池。

连接到间谍摄像头的界面

在浏览器窗口中，在同一Wi-Fi网络上打开您之前找到的ESP32-CAM的IP地址。这将使您能够访问间谍摄像头的设置。您可以更改分辨率、视频质量、亮度、对比度和饱和度，直到获得所需的图像，以及添加特殊效果和调整其他选项。

在菜单底部，您将看到"人脸检测"和"人脸识别"选项，可以切换打开。目前，它仅适用于400 x 296及以下的分辨率。

点击底部的"开始流"以查看视频流。如果您只打开了人脸检测，您应该看到任何人头部周围的框，以知道它正在工作。如果打开了人脸识别，它将执行相同的操作，但还会命名面部，最初将是入侵者。您可以点击"注册面部"按钮将其注册为非入侵者。

将此设备隐藏在任何地方

这些板可能会变得相当热，因此根据您的电池和运行摄像头的时间长短，它可能无法工作或会关闭。如果发生这种情况，请考虑使用适当的散热器来散热并保持冷却。您添加到间谍摄像头上的东西越多，将其隐藏在不起眼的地方就越困难，请记住这一点。

comments powered by Disqus
© 2020 - 2025 qife
使用 Hugo 构建
主题 Stack 由 Jimmy 设计
本站总访问量次 本站访客数人次